*******************************************************
* Taiwan Semiconductor
* TSM60NC620CI
* N-Channel 600V
* Date: 2023-10-26
* Version: 1
*******************************************************
.SUBCKT TSM60NC620CI D G S
M1 3 GX S S NMOS W= 888188u L= 2u 
M2 S GX S D PMOS W= 628188u L= 1.640u   
R1 D 4 4.35046e-01 TC=10.8e-03,0.355e-04
J1 4 S 3 JD 628188u 
.MODEL JD NJF (VTO = -7.10  BETA = 10.339e-01 LAMBDA = 0.626e-02 
+BETATCE = -0.0e-01 VTOTC = -0.0
+IS = 1e-18 N = 10 )
CGS GX S 2.e-12 
CGD GX D 0.524e-12 
RG G GY 1m 
RTCV 100 S 1e6 TC=-0.500e-03,0
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD
DBD2 S D DBD2
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 10e-8 
+ RS = 0 KP = 24.56e-06 NSUB = 12.543e+16 theta=0.15
+ NFS = 3.897e+11  
+ LD = 0 IS = 0 TPG = 1 )
*************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 10e-8 
+NSUB = 3.300e+15 IS = 0 TPG = -1    )
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 0.614E-6 T_measured = 25 BV = 670
+TBV1=1.178E-03 TBV2=-1.232E-06  IKF=3.4740
+RS = 10.951E-3 N = 1.2242 IS = 26.740E-12
+XTI = 4.25e+00 TRS1 = 1.99e-03
+CJO = 2.7091E-9 VJ = 15.2100 M = 2.69 )  
****************************************************************
.MODEL DBD2 D ( 
+FC = 0.1 TT = 0 T_measured = 25 BV = 670
+TBV1=1.178E-03 TBV2=-1.232E-06 
+N = 1000 IS = 0E-1
+CJO = 14.0E-12 VJ = 0.6500 M = 0.1)
****************************************************************
.ENDS