*******************************************************
* Taiwan Semiconductor
* TSM60NC390CP
* N-Channel 600V
* Date: 2023-12-18
* Version: 1
*******************************************************
.SUBCKT TSM60NC390CP D G S
M1 3 GX S S NMOS W= 1261227u L= 2u 
M2 S GX S D PMOS W= 1261227u L= 1.60498u   
R1 D 4 279.447e-03 TC=10.88e-03,0.370e-04
J1 4 S 3 JD 1261227u 
.MODEL JD NJF (VTO = -7.10  BETA = 10.339e-01 LAMBDA = 0.626e-02 
+BETATCE = 0.0e-01 VTOTC = -0.0
+IS = 1e-18 N = 10 )
CGS GX S .1e-12 
CGD GX D 0.3e-12 
RG G GY 1m
RTCV 100 S 1e6 TC=0.650e-03,-12.20e-6
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD
CDS S D 17.01p

**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 10e-8 
+ RS = 0 KP = 38.56e-06 NSUB = 12.783e+16 theta=0.15 VMAX=0.6e5
+ NFS = 3.282e+11  
+ LD = 0 IS = 0 TPG = 1 )
*************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 10e-8 
+NSUB = 2.000e+15 IS = 0 TPG = -1    )
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 584.69E-9  T_measured = 25 BV = 681
+TBV1=1.0250E-03  TBV2=-5.9190E-07  IKF=4.8163
+RS = 7.3037E-3 N = 1.1913 IS = 20.529E-12  EG=1.16
+XTI = 2.8e+00 TRS1 = 2.94e-03
+CJO = 4.3397E-9 VJ = 16 M = 2.98)  
****************************************************************   

.ENDS